例1 简支梁-ANSYS模态分析及结果输出

2017-01-16 by:CAE仿真在线来源:互联网

/FILNAME,Simple Beam,0
/CWD,'F:\AnsysGlobalMatrix'
/TITLE,Simple Beam
/PREP7
!截面积
AREA = 1.67e-3
!惯性矩
IZZ = 1.6652e-6
!高度
H = SQRT(12*IZZ/AREA)
!计算模态数
MN =6
!总结点数
NOD_N =6
!单元结点自由度
DOF = 3
!单元
ET,1,BEAM3
!实常数
R,1,AREA,IZZ,H
!定义材料
MP,DENS,1,7850
MP,EX,1,2E11
MP,PRXY,1,0.3
!建立节点
CSYS0
*DO,I,1,NOD_N
N,I,0.5*(I-1),0,0,
*ENDDO
!建立单元
*DO,I,1,NOD_N-1
!单元类型
TYPE,1
!单元材料
MAT,1
!单元实常数
REAL,1
ESYS,0
!建单元
E,I,I+1
*ENDDO
/SOLVE
!模态分析
ANTYPE,2
!朗兹法计算MN阶振型,并关于质量矩阵归一化
MODOPT,LANB,MN,0,0, ,OFF
EQSLV,SPAR
MXPAND,MN

!约束
D,1, , , , , ,UX,UY
D,6,UY

!求解
SOLVE
/POST1
!模态列表显示
SET,LIST

*DIM,FREQ_HZ,ARRAY,1,MN
*DO,I,1,MN
*GET,FREQ_HZ(1,I),MODE,I,FREQ
*ENDDO

*MWRITE,FREQ_HZ,FREQ,TXT, ,IJK,1,MN, ,
(F10.4)

*DIM,MODE,ARRAY,NOD_N,DOF
*DIM,NAME,CHAR,10,1
NAME(1) = 'MOD01','MOD02','MOD03','MOD04','MOD05','MOD06','MOD07','MOD08','MOD09','MOD10'
SET,FIRST
*DO,K,1,MN
*DO,I,1,NOD_N
*GET,MODE(I,1),NODE,I,U,X
*GET,MODE(I,2),NODE,I,U,Y
*GET,MODE(I,3),NODE,I,ROT,Z
*ENDDO
*MWRITE,MODE,NAME(K),TXT, ,JI,DOF,NOD_N
(1E20.8)
SET,NEXT
*ENDDO
FINISH
/AUX2
FILE,'ContinuousBeam','full',' '
HBMAT,'stiffness',' ',' ',ASCII,STIFF,YEs
HBMAT,'mass',' ',' ',ASCII,MASS,YES

开放分享：优质有限元技术文章,助你自学成才