梁的应力变形ANSYS分析，分别受集中力、集中力偶和均布载荷作用

2017-02-17  by:CAE仿真在线  来源:互联网

---

导读:受弯曲变形,用梁单元BEAM188建模分析。梁单元的单元属性有单元类型、截面属性和材料属性。掌握施加位移约束和载荷的方法,特别是均布载荷的施加。熟练进行后处理,包括约束反力、内力、应力和变形,特别是剪力图和弯矩图与材料力学的对比,切应力和正应力云图的提取方法。

---

一、问题描述

一简支梁,总长l =0.4m,其中a= b = l/2,横截面尺寸B = 6mm,H=10 mm,弹性模量E= 200 GPa,泊松比u = 0.3。分别受三种载荷作用:(1)受集中力F =100 N;(2)集中力偶Me= 20 N·m;(3)受均布载荷q =500 N/m。计算梁的约束反力、内力(剪力和弯矩)、应力(切应力和正应力)和变形(转角和挠度)。

二、理论计算

参考教材:刘鸿文. 材料力学(第5版) [M]. 北京: 高等教育出版社, 2011: 110-209.

二、GUI步骤

1.进入ANSYS

程序→ ANSYS → ANSYS Product Launcher → 改变working directory到指定文件夹→ 在job name输入:file → Run。

2.定义工作文件名及工作标题

(1)定义工作文件名:UtilityMenu > File > Change Jobname → Change Jobname → 输入文件名file→ OK。可不用输入,默认为file。

(2)定义工作标题:UtilityMenu > File > Change Title → Change Title → 输入Beam→ OK。可不用输入。

3.定义单元属性

(1)定义单元类型:

①指定BEAM188单元:MainMenu >Preprocessor >Element Type >Add/Edit/Delete→Add→在左列表框中选择Beam,在右列表框中选择2node 188 →OK。

②设置单元选项:Options→Element behavior K3:Cubic Form(三次形函数);Shear stress output K4:Include Both →OK。默认情况下Element behavior是一次形函数,Shear stress output只输出扭转切应力,不输出剪力产生的切应力。因此,需做如上修改,改成三次形函数和输出切应力。

(2)定义截面:MainMenu >Preprocessor >Sections >Beam >Common Sections →ID:1,在Sub-Type下拉框选择实心圆形截面图形,B:10,H:6,NB:0,NH:0,→ Meshview →Meshview →OK。

默认情况下高度为H,宽度为B,高度沿坐标系的Z方向。想要本例高度沿Y方向,将B和H的数值交换一下即可。图中Area是面积、Iyy和Izz是惯性矩。

Nb和Nh默认情况下,剪力产生的切应力有一定误差。Nb和Nh分别输入20份,就能接近解析解。

(3)设置材料属性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2.00E5,PRXY:0.3→ OK。200 GPa=2.00E5 MPa。

4.建立几何模型

(1)生成关键点:Main Menu >Preprocessor>Modeling >Create >Keypoints >In Active CS →依次输入关键点的编号和坐标:1 (0,0,0),2 (200,0,0),3 (400,0,0) →OK。

(2)创建直线:MainMenu >Preprocessor >Modeling >Create >Lines >Lines >Straight Line →依次拾取1和2,2和3,创建2条直线→OK。

(3)打开线编号:Utility Menu > PlotCtrls > Numbering→KP Keypoint numbers:ON,LINE Line numbers:ON→ OK。

5.划分网格

(1)设置线的单元属性:MainMenu >Preprocessor >Meshing >Mesh Tool →在Element Attributes下方选择Lines Set→ 拾取线1→OK→选择MAT:1,TYPE:1,SECT:1→OK。单元类型编号、截面编号和材料编号只有一种,可默认,不需要指定,此步骤可省略。

(2)设置单元尺寸:MainMenu >Preprocessor >Meshing >Mesh Tool →在Size Controls下方选择Global Set →SIZE: 20 →OK。每20mm划分一个单元。

(3)划分梁单元:MainMenu >Preprocessor >Meshing >Mesh Tool →Mesh:Lines→ Mesh → Pick All。

(4)打开梁单元的单元形状:Utility Menu >PlotCtrls>Style >Size and Shape → [/ESHAPE]: On。

(5)显示单元:Utility Menu > Plot > Element。

6.施加边界条件

(1)施加约束:MainMenu >Solution >Define Loads >Apply >Structura l>Displacement >OnKeypoints

→拾取关键点1→ OK → Lab2:UX、UY、UZ和ROTX→ Apply

→拾取关键点3→ OK → Lab2:UX和UZ→ OK。

将导致如下错误,提示约束不足。虽然没有施加扭矩,但绕自身轴扭转是自由的,也应约束扭转自由度ROTX,。约束后,便能求解。

(2)施加载荷:分别施加集中力、集中力偶和均布载荷的方法如下。

①施加集中力:MainMenu >Solution >Define Loads >Apply >Structural >Force/Moment >OnKeypoints → 拾取关键点2→ OK → Lab:FY,VALUE:100 →OK。注意单位是N。

②施加集中力偶:MainMenu >Solution >Define Loads >Apply >Structural >Force/Moment >OnKeypoints → 拾取关键点2→ OK → Lab:MZ,VALUE:20e3 →OK。注意单位是N.mm。

③施加均布载荷:MainMenu >Solution >Define Loads >Apply >Structural >Pressure >On Beams →Pick All→ LKEY:2,VALI:500e-3,VALJ:500e-3→OK。注意单位是N/mm。

施加均布载荷的说明:根据实例中的坐标,均布载荷应在-Y方向施加。

A.打开梁单元的单元坐标系:UtilityMenu >PlotCtrls >Symbols → ESYS:On→OK。

B.检查梁单元的单元坐标系,看不清请把单元形状关掉,检查后再把单元形状打开。单元坐标系的X、Y和Z坐标与整体坐标系相同。经查,该实例的单元坐标系与整体坐标系一致。

C.查看在单元坐标系下施加均布载荷的编号:打开ANSYS帮助→索引中选择Beam188→回车 →在Beam188单元说明查看“BEAM188Geometry”说明。可见梁单元坐标系的-Y方向施加的均布载荷的编号为②,数值应是加正值。

(3)求解前保存模型:UtilityMenu > Files > Save as → 输入Beam_Load.db→ OK。

7.求解

(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve CurrentLoad Step → OK → Solution is done → Close。

(2)保存结果文件:UtilityMenu > Files > Save as → 输入file.db→ OK。

8.后处理

(1)列表查看约束反力:MainMenu > General Postproc > List Results > Reaction Solu → All strucforc F → OK。记录数值。

(2)查找定义内力(剪力和弯矩)单元表的方法

①查找定义BEAM188内力单元表的方法:打开ANSYSHelp,搜索BEAM188。

找到BEAM188的单元介绍页面后,页面中查表Table188.1: BEAM188 Element Output Definitions。表中查找Name:SF:y,z,Definition:Section shear forces,在Name栏中SFy便是剪力。

表中查找Name:My,Mz,Definition:Bending moments,在Name栏中MZ便是弯矩。

页面中查表Table188.2: BEAM188 Item and Sequence Numbers。表中查找Output Quantity Name:剪力SFy,Item:SMISC,I:6,J:19。弯矩Mz,Item:SMISC,I:3,J:16。

(3)查看各单元剪力

①定义剪力单元表:MainMenu > General Postproc > Element Table > Define Table → Lab:输入SFY_I→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“6” →OK → Apply → Lab:输入SFY_J→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“19”→ OK → Close。

②剪力列表:MainMenu > General Postproc > Element Table > List Element Table → 选择SFY_I和SFY_J→ OK → 记录弯矩值→ File → Close。

③剪力云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择SFY_I,LabJ选择SFY_J→ OK。

(4)查看各单元弯矩

①定义弯矩单元表:MainMenu > General Postproc > Element Table > Define Table → Lab:输入MZ_I→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“3” →OK → Apply → Lab:输入MZ_J→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“16”→ OK → Close。

②弯矩列表:MainMenu > General Postproc > Element Table > List Element Table → 选择MZ_I和MZ_J→ OK → 记录弯矩值→ File → Close。

③弯矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择MZ_I,LabJ选择MZ_J→ OK。

④将弯矩单位N.mm转换成N.m:Main Menu >General Postproc >Element Table>Add Items → LabR:MZ_I,FACT1:1e-3,Lab1:MZ_I → Apply → LabR:MZ_J,FACT1:1e-3,Lab1:MZ_J → OK。

⑤重新画弯矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择MZ_I,LabJ选择MZ_J→ OK。

(5)应力云图(切应力和正应力)

①切应力云图:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu → XY Shear stress → OK。

②正应力云图:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu → X-Componentstress → OK。

(6)弯曲变形(挠度和转角)

①挠度云图:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → Y - Component of displacement→OK。

②转角云图:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → Z - Component of rotation→OK。

9.退出ANSYS软件

Utility Menu> File > Exit → Quit-No Save → OK。

四、结果及讨论

1.ANSYS计算结果与解析解对比

2.计算结果云图

(1)集中力作用

①剪力图和弯矩图

②切应力和正应力

③挠度和转角

(2)集中力偶作用

①剪力图和弯矩图

②切应力和正应力

③挠度和转角

3.均布载荷作用

①剪力图和弯矩图

②切应力和正应力

③挠度和转角

五、APDL步骤

FINISH

/CLEAR,NOSTART

/PREP7

ET,1,BEAM188 !单元类型

KEYOPT,1,3,3 !形函数

KEYOPT,1,4,2 !切应力

MP,EX,1,2.00e5 !材料属性MPa

MP,PRXY,1,0.3

SECTYPE, 1, BEAM, RECT, ,0 !截面属性mm

SECOFFSET, CENT

SECDATA,10,6,0,0,0,0,0,0,0,0,0,0

!SECTYPE, 1, BEAM, RECT, ,0 !截面属性,切应力精度提高

!SECOFFSET, CENT

!SECDATA,10,6,20,20,0,0,0,0,0,0,0,0

K,1,0,0,0, !创建关键点mm

K,2,200,0,0,

K,3,400,0,0,

L,1,2 !创建线

L,2,3

/PNUM,KP,1 !关键点编号

/PNUM,LINE,1 !线编号

LATT,1, ,1, , , ,1 !线的单元属性

LESIZE,ALL, , ,20, , , , ,1 !单元尺寸mm

LMESH,ALL !线分网

/ESHAPE,1.0 !单元形状

DK,1,UX !施加位移约束

DK,1,UY

DK,1,UZ

DK,1,ROTX

DK,3,UY

DK,3,UZ

FK,2,FY,-100 !集中力N

!FK,2,MZ,20e3 !集中力偶N.mm

!SFBEAM,ALL,2,PRES,500e-3,500e-3, , , , ,0 !均布载荷N/mm

FINISH

/SOLU

SOLVE !求解

FINISH

/POST1

/UDOC,1,DATE,1 !关闭ANSYS标志和时间

/dev,font,1,Courier*New,400,0,-21,0,0,,, !3号字体

PRRSOL,F !约束反力列表

ETABLE,SFY_I,SMISC, 6 !定义剪力单元表

ETABLE,SFY_J,SMISC, 19

/VIEW,1,,,1 !视图

PLLS,SFY_I,SFY_J,1,0 !剪力图云图

PRETAB,SFY_I,SFY_J !剪力列表

ETABLE,MZ_I,SMISC, 3 !定义弯矩单元表

ETABLE,MZ_J,SMISC, 16

/VIEW,1,,,1 !视图

PLLS,MZ_I,MZ_J,1,0 !弯矩图云图

PRETAB,MZ_I,MZ_J !弯矩列表

SADD,MZ_I,MZ_I, ,1E-3,1, , !将弯矩单位N.mm转换成N.m

SADD,MZ_J,MZ_J, ,1E-3,1, ,

PLLS,MZ_I,MZ_J,1,0 !弯矩图云图

PLNSOL, S,X, 0,1.0 !弯曲正应力

PLNSOL, S,XY, 0,1.0 !切应力

PLNSOL, U,Y, 0,1.0 !挠度

PLNSOL, ROT,Z, 0,1.0 !弯曲角rad

相关标签搜索：梁的应力变形ANSYS分析，分别受集中力、集中力偶和均布载荷作用 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训