搜索哪种桁架更安全合理？清晰合理的受力形式，实现材料充分利用
2017-02-20 by:CAE仿真在线 来源:互联网
导读:根据生活常识和所学知识,首先定性分析,然后定量计算分析。
一、问题描述
这两种桁架,哪一个更安全合理一些?
二、问题分析
初看之下,只有腹杆的方向相反。但是细细想一下,发现腹杆反向差别很大,甚至两种桁架的受力状态完全不同:
桁架1:直接判断6,9,12全是零杆。再者,根据节点静力平衡,1,8,14,15均为压杆,沿2,8,15杆“切一刀”,根据截面平衡法,2是拉杆(支座处没有水平力)。这样,整个桁架相当于两个平行四边形组成的“半圆拱”,下部用两根拉杆相连。外侧的两个集中荷载由单柱承受。这样的结构是很不合理的,不但浪费材料,而且压杆稳定性也很难保证。显然这样不合理的结构是不能采取的。
桁架2:底部弦杆1和4是零杆。倾斜的腹杆均受拉(腹杆较长,受压比较危险!),形成一个倒梯形的有效受力桁架体系,各杆能发挥作用,材料利用率较高。所以说,桁架2是比桁架1更安全合理的结构。
三、结果分析与讨论
建模计算需要的参数有:横杆和竖杆的长度为0.2m,横截面面积为100 mm2,弹性模量E= 200 GPa,泊松比u = 0.3,载荷F = 1 kN。
经过ANSYS建模计算,以下是两桁架的轴力图和轴力列表,可见上述定性分析是正确的。
(1)桁架1的轴力图
(2)桁架2的轴力图
(3)桁架1和桁架2的轴力计算结果对比
这只是个小例子,但由此可以体会到,结构中材料的充分利用是要依靠清晰合理的受力形式。当能做到用最省的材料承受最大的荷载时,才是最经济合理的结构。结构的美在于简单精巧,没有冗余!
四、GUI求解步骤
1.进入ANSYS
程序→ ANSYS → ANSYS Product Launcher → 改变working directory到指定文件夹→ 在job name输入:Link → Run。job name可默认为file。
2.定义工作文件名及工作标题
(1)定义工作文件名:UtilityMenu > File > Change Jobname → Change Jobname → 输入文件名Link→ OK。可不用输入,默认为file。
(2)定义工作标题:UtilityMenu > File > Change Title → Change Title → 输入Link→ OK。可不用输入。
3.定义单元属性
(1)定义单元类型:MainMenu > Preprocessor > Element Type > Add/Edit/Delete → Add → 在左列表框中选择Link,在右列表框中选择3D finit stn 180 → OK → Close。
(2)定义实常数:MainMenu > Preprocessor > Real Constants > Add → Type 1 → OK → RealConstant Set No.:1,AREA:100→ OK → Close。
(3)设置材料属性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2.0E5,PRXY:0.3→ OK。
4.建立模型
(1)定义节点:MainMenu > Preprocessor > Create > Nodes > In Active CS → 依次输入10个节点的节点编号和坐标→OK。
(2)定义单元:
①定义单元:MainMenu > Preprocessor > Create > Elements > Auto Numbered > Thru Nodes → 按照杆的编号,依次拾取节点,生成单元→ OK。
②打开节点和单元编号:Utility Menu > PlotCtrls > Numbering→ NODE numbers:ON,Elem/Attribnumbering: Element numbers。→ OK。
③显示单元:Utility Menu > Plot > Element,查看节点和单元编号。
④打开杆单元的单元形状:Utility Menu > PlotCtrls> Style > Size and Shape → [/ESHAPE]: On。
5.施加边界条件并求解
(1)施加约束:MainMenu > Solution > Define loads > Apply > Structural > Displacement> On Nodes → 拾取节点1→ OK → Lab2:AllDOF → Apply → 拾取节点9→Lab2:UY→ OK。
(2)在上排节点施加载荷:
①选择上排节点:UtilityMenu >Select >Entities → 见下图→OK。
②施加载荷:MainMenu > Solution > Define loads > Apply > Structural > Force/Moment> On Nodes → Pick All → Lab:FY,VALUE:-1e3→ OK。
③选择所有:UtilityMenu >Select >Everything。求解器前务必选择所有,否则计算失败。
(3)求解前保存模型:UtilityMenu > Files > Save as → 输入Link_Load.db→ OK。
6.求解
(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve CurrentLoad Step → OK → Solution is done → Close。
(2)保存结果文件:UtilityMenu > Files > Save as → 输入Link_Solve.db→ OK。
7.轴力后处理
(1)查定义LINK180轴力单元表的方法:打开ANSYSHelp,搜索LINK180。
找到LINK180的单元介绍页面后,找Table180.1: LINK180 Element OutputDefinitions,在Name栏中FORCE便是轴力。
找Table 180.2:LINK180 Item and Sequence Numbers,表中OutputQuantity Name列找到FORCE,Item为SMISC,编号为1。
(2)定义轴力单元表:MainMenu > General Postproc > Element Table > Define Table,→ Lab:输入FN→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“1” → OK → Close。
(3)轴力列表显示:Main Menu > General Postproc > Element Table> List Element Table → 选择FN → OK → 记录各个单元的轴力 → File → Close。
(4)画轴力图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择FN,LabJ选择FN→ OK。
8.退出ANSYS软件
Utility Menu> File > Exit → Quit-No Save → OK。
五、APDL求解步骤
!--------------------------------------------第1种桁架
/PREP7 !进入前处理
ET,1,LINK180 !单元类型1
R,1,100 !实常数1
MP,EX,1,2.0e5 !材料1
MP,PRXY,1,0.3
N,1,0,0,0 !定义节点
N,2,0,0.2e3,0
NGEN,5,2,ALL, , ,0.2e3, , ,1,
E,1,3 !定义单元
E,3,5
E,5,7
E,7,9
E,9,10
E,10,8
E,8,6
E,6,4
E,4,2
E,1,2
E,3,4
E,5,6
E,7,8
E,1,4 !斜杆
E,3,6
E,6,7
E,8,9
FINISH
/SOLU !进入求解器
D,1,ALL !施加约束
D,9,UY
NSEL,S,LOC,Y,0.2e3 !由y坐标选择节点
F,ALL,FY,-1e3 !施加载荷
ALLSEL,ALL !选择所有
SOLVE !求解
FINISH
/POST1 !后处理
ETABLE,FN,SMISC, 1 !定义轴力单元表
PRETAB,FN !列表显示轴力单元表
PLLS,FN,FN,1,0 !云图显示轴力图
!--------------------------------------------第2种桁架
/PREP7 !进入前处理
ET,1,LINK180 !单元类型
R,1,100 !实常数
MP,EX,1,2.0e5 !材料
MP,PRXY,1,0.3
N,1,0,0,0 !定义节点
N,2,0,0.2e3,0
NGEN,5,2,ALL, , ,0.2e3, , ,1,
E,1,3 !定义单元
E,3,5
E,5,7
E,7,9
E,9,10
E,10,8
E,8,6
E,6,4
E,4,2
E,1,2
E,3,4
E,5,6
E,7,8
E,2,3 !斜杆
E,4,5
E,5,8
E,7,10
FINISH
/SOLU !进入求解器
D,1,ALL !施加约束
D,9,UY
NSEL,S,LOC,Y,0.2e3 !由y坐标选择节点
F,ALL,FY,-1e3 !施加载荷
ALLSEL,ALL !选择所有
SOLVE !求解
FINISH
/POST1 !后处理
ETABLE,FN,SMISC, 1 !定义轴力单元表
PRETAB,FN !轴力列表
PLLS,FN,FN,1,0 !轴力云图
来源:程晓波的博客,结构定性分析例四。好学ANSYS整理,并用ANSYS进行了计算。
相关标签搜索：哪种桁架更安全合理？清晰合理的受力形式，实现材料充分利用 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训
