Ansys：施加随坐标变化的压力载荷

2017-03-02 by:CAE仿真在线来源:互联网

在实际工作中,经常需要在结构表面上施加压力,并且压力不是均匀分别得,而是随结构表面位置变化而分布。如果在实体结构表面施加不均匀分布压力,需要在实体表面先覆盖一层表面效应单元SURF153或者SURF154,然后在表面效应单元上施加这种压力,此时与在壳体上施加载荷一样进行处理。

eg:在一个长度和宽度为10m,厚度为0.1m壳体上施加按下来函数p(x,y)=c0+c1*x**3+c2*y**3

!创建随函数分布得压力通用宏:press_funct.mac
*create,press_funct,mac
cm,e_sel,elem
!******提取所有单元编号******
*get,ecount,elem,,count
*dim,enum,array,ecount
*get,enum(1),elem,,num,min
*do,i,2,ecount
enum(i)=elnext(enum(i-1))
*enddo
!******按单元定义每个单元压力******
!pn(x,y)=c0+c1*x**3+c2*y**3
c0=0.1
c1=5
c2=5
*do,i,1,ecount
esel,s,,,enum(i)
nsel,r
*get,n_e,node,,count
xn=nx(nelem(enum(i),1))
yn=ny(nelem(enum(i),1))
zn=nz(nelem(enum(i),1))
pn1=c0+c1*xn**3+c2*yn**3
xn=nx(nelem(enum(i),2))
yn=ny(nelem(enum(i),2))
zn=nz(nelem(enum(i),2))
pn2=c0+c1*xn**3+c2*yn**3
xn=nx(nelem(enum(i),3))
yn=ny(nelem(enum(i),3))
zn=nz(nelem(enum(i),3))
pn3=c0+c1*xn**3+c2*yn**3
pn4=0
*if,n_e,eq,4,then
xn=nx(nelem(enum(i),4))
yn=ny(nelem(enum(i),4))
zn=nz(nelem(enum(i),4))
pn4=c0+c1*xn**3+c2*yn**3
*endif
sfe,enum(i),1,pres,,pn1,pn2,pn3,pn4
*enddo
cmsel,s,e_sel
!******删除宏内部应用的变量******
cmdele,e_sel
xn=
yn=
zn=
pn1=
pn2=
pn3=
n_e=
ecount=
enum(1)=
anum=
*end
!******
!主程序
finish
/filname,byb
/prep7
et,1,shell63
r,1,0.1
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800
rectng,-5,5,-5,5
esize,1
mshape,0,2d
mshkey,1
amesh,all
/psf,pres,norm,2,0
press_funct
eplot
allsel,all
finish
save