搜索ANSYS流固耦合实例
2017-03-03 by:CAE仿真在线 来源:互联网
发一个流固耦合的例子,希望对正在学流体分析的有帮助
换热器分析:
换热器由两种成份构成,采用逆流。由一个固体隔开。
分两步求解:
第一步只进行流体分析,第二步进行温度分析。
fini
/filname,Exercise17 ! 定义CFD分析文件名
/prep7 ! 进入前处理器
LX = 10
NDX = 10
LY1 = 2
LY2 = 0.1
LY3 = 1.0
NDY1 = 10
NDY2 = 3
NDY3 = 10
YOFFSET = 0 ! 定义各参数
et,1,141 ! 选择单元
keyopt,1,1,2 ! 将流体设置为两组分
esha,2 ! 选择平面划分单元方式
rect,,LX,YOFFSET,YOFFSET+LY1 ! 建立流体区域1的几何模型
rect,,LX,YOFFSET+LY1,YOFFSET+LY1+LY2 ! 建立固体区域的几何模型
rect,,LX,YOFFSET+LY1+LY2,YOFFSET+LY1+LY2+LY3 ! 建立流体区域2的几何模型
nummrg,all ! 合并关键点
numcmp,all ! 压缩编号
lsel,s,,,3,9,3
lsel,a,,,1
lesi,all,,,NDX, ! 划分横向各直线的单元密度
lsel,s,,,2,4,2
lesi,all,,,NDY1,-5.0 ! 划分流体区域1竖向各直线的单元密度
lsel,s,,,5,7,2
lesi,all,,,NDY2,-5.0 ! 划分固体区域竖向各直线的单元密度
lsel,s,,,8,10,2
lesi,all,,,NDY3,-5.0 ! 划分流体区域2竖向各直线的单元密度
allsel,all
mat,1 ! 定义流体材料号
amesh,1 ! 划分流体区域1的单元
amesh,3 ! 划分流体区域2的单元
mat,2 ! 定义固体材料号
amesh,2 ! 划分固体区域的单元密度
!inner region 1 ! 定义流体区域1的边界条件
!bc inlet ! 定义流体区域1进口边界条件
lsel,s,,,4
nsll,s,1
d,all,pres,10 ! 定义流体区域1进口压力边界条件
d,all,temp,100 ! 定义流体区域1温度边界条件
!bc outlet ! 定义流体区域1出口边界条件
lsel,s,,,2
nsll,s,1
d,all,pres,0 ! 定义流体区域1出口压力边界条件
!symm ! 定义对称面约束条件
lsel,s,,,1
nsll,s,1
d,all,vy,0 ! 定义对称面速度约束条件
!region 2 ! 定义流体区域2的边界条件
!bc inlet ! 定义流体区域2进口边界条件
lsel,s,,,8
nsll,s,1
d,all,pres,10. ! 定义流体区域2进口压力边界条件
d,all,temp,400 ! 定义流体区域2温度边界条件
!bc outlet ! 定义流体区域2出口边界条件
lsel,s,,,10
nsll,s,1
d,all,pres,0. ! 定义流体区域2出口压力边界条件
!top wall ! 定义顶面的边界约束条件
lsel,s,,,9
nsll,s,1
d,all,vx,0
d,all,vy,0 ! 定义顶面的速度约束边界条件
allsel
!solid properties ! 定义固体的材料参数
mp,dens,2,5. ! 定义密度
mp,kxx,2,100 ! 定义热传导系数
mp,c,2,13 ! 定义比热
/solu ! 进入求解器
!ic for species ! 定义流体组分
nsel,s,loc,x,,lx
nsel,r,loc,y,0,ly1
ic,all,sp01,1.0
ic,all,sp02,0.0 ! 定义流体区域1材料组分
nsel,s,loc,x,,lx
nsel,r,loc,y,ly1+ly2,ly1+ly2+ly3
ic,all,sp01,0.0
ic,all,sp02,1.0 ! 定义流体区域2材料组分
allsel
! 第一步:进行流体场分析
flda,iter,exec,200 ! 定义迭代次数
flda,prot,dens,cmix ! 定义流体密度
flda,prot,visc,cmix ! 定义流体粘度
flda,prot,cond,cmix ! 定义流体热传导系数
flda,prot,spht,cmix ! 定义流体比热
flda,vary,dens,t
flda,vary,visc,t
flda,vary,cond,t
flda,vary,spht,t ! 定义流体各材料参数为变化的
flda,nomi,dens,1 ! 定义流体区域的初始密度
flda,nomi,visc,2 ! 定义流体区域的初始粘度
flda,nomi,cond,3 ! 定义流体区域的初始热传导系数
flda,nomi,spht,4 ! 定义流体区域的初始比热
msprop,1,spht,constant,1 ! 定义流体1组分比热
msprop,2,spht,constant,2 ! 定义流体2组分比热
msprop,1,dens,constant,1 ! 定义流体1组分密度
msprop,2,dens,constant,2 ! 定义流体2组分密度
msprop,1,visc,constant,1.0 ! 定义流体1组分粘度
msprop,2,visc,constant,2.0 ! 定义流体2组分粘度
msprop,1,cond,constant,.1 ! 定义流体1组分热传导系数
msprop,2,cond,constant,.2 ! 定义流体2组分热传导系数
flda,conv,pres,1e-10
flda,term,pres,1e-9
flda,outp,sp01,t
flda,outp,sp02,t ! 定义流体场求解控制
solve ! 进行流体场求解
/post1 ! 进入通用后处理器
set,last ! 读取最后载荷步的分析结果
plnsol,pres,,0, ! 显示压力分布云图
plvect,v,,,,vect,elem,on,0 ! 显示速度矢量分布图
! 第二步:进行温度场求解
/solu ! 进入求解器
flda,solu,enrg,t
flda,solu,flow,f
flda,meth,enrg,3
flda,iter,exec,50
flda,relx,temp,1 ! 定义温度场求解控制
solve ! 进行温度场求解
/post1 ! 进入通用后处理器
set,last ! 读取最后载荷步的分析结果
plnsol, temp,,0, ! 显示温度分布云图
fini
/exit,nosav ! 退出ANSYS
相关标签搜索：ANSYS流固耦合实例 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训
