搜索弹塑性专题-三杆对称桁架理想弹塑性ANSYS分析
2017-03-05 by:CAE仿真在线 来源:互联网
导读:理想弹塑性材料模型用双线性随动强化模型。弹性极限载荷、塑性极限载荷和卸载,按照载荷步,依此施加载荷,设置载荷子步和自动时间步长,求解。后处理的竖直位移变形在直角坐标系下参看,应力和应变在单元坐标系下查看。
一、问题描述
有一个三杆桁架,受竖直向下的载荷F作用,竖杆长度L=100 mm,横截面积A=10 mm2,弹性模量E=200 GPa,泊松比为0.3,角度为45°,屈服强度为250 MPa。在弹性极限载荷、塑性极限载荷和卸载后的条件下,计算竖直位移、各杆应力和应变。例子来源于塑性力学教材。
问题分析
桁架用LINK180杆单元,理想弹塑性材料模型用双线性随动强化模型。弹性极限载荷、塑性极限载荷和卸载,按照载荷步,依此施加载荷,设置载荷子步和自动时间步长,求解。后处理的竖直位移变形在直角坐标系下参看,应力和应变在单元坐标系下查看。
计算结果
根据解析公式,表中弹性极限载荷Fe= 4267.8N,塑性极限载荷Fp= 6035.5N。
表中蓝色字体与解析解完全吻合,验证了ANSYS的计算结果是正确的。
对于理想弹塑性模型,塑性应变不承载,应力为弹性模量乘以弹性应变。
总应变等于弹性应变加上塑性应变。
卸载后,杆①和杆③是弹性应变3.66E-04;杆②既有弹性应变-5.18E-04,也有塑性应变1.25E-03,弹性应变加上塑性应变等于总应变7.32E-04。
1.结果汇总
2.云图结果
(1)卸载后残余变形云图
(2)应力云图
(a)弹性极限载荷作用下的应力云图,中间杆先屈服
(b)塑性极限载荷作用下的应力云图,所有杆都屈服
(c)卸载后的残余应力云图
(3)卸载后的各种应变
(a)卸载后的弹性应变云图
(b)卸载后的塑性应变云图
(c)卸载后的总应变云图
二、理论计算
参考文献:王春玲. 塑性力学 [M]. 北京: 中国建材工业出版社, 2005:6-10
三、GUI步骤
1.进入ANSYS
程序→ANSYS→ANSYS Product Launcher→改变working directory到指定文件夹→在job name输入:Link→Run。job name可默认为file。
2.定义单元属性
(1)定义单元类型:MainMenu >Preprocessor >Element Type >Add/Edit/Delete →Add →在左列表框中选择Link,在右列表框中选择3D finit stn 180 →OK →Close。
(2)定义实常数:MainMenu >Preprocessor >Real Constants >Add →Type 1 →OK →Real Constant→ Set→ No.:1;AREA:10→OK →Close。
(3)设置材料属性:
①弹性模量和泊松比:MainMenu >Preprocessor >Material Props >Material Models →Structural →Linear → Elastic →Isotropic →EX:2E5;PRXY:0.3→OK。
②理想弹塑性模型:Main Menu>Preprocessor >Material Props >Material Models →Structural →Nonlinear → 见下图 →双击Bilinear(双线性)→Yield Stress:250;Tang Mods:0 →OK。关键步骤!双线性随动强化(BKIN)可定义理想弹塑性模型。
3.建立模型
(1)定义节点:MainMenu >Preprocessor >Create >Nodes > In Active CS →依次输入4个节点坐标1(-100,0,0),2(0,0,0),3(100,0,0),4(0,-100,0)→OK。
(2)定义单元:
①定义单元:MainMenu >Preprocessor >Create >Elements >Auto Numbered >Thru Nodes→拾取节点1和4→Apply →拾取节点2和4→Apply →拾取节点3和4→OK。
②打开杆单元的单元形状:UtilityMenu>PlotCtrls>Style>Size and Shape →[/ESHAPE]: On。
4.施加位移约束
(1)施加位移约束MainMenu > Solution > Define loads > Apply > Structural >Displacement > On Nodes →拾取节点1、2和3→OK →Lab2:All DOF →OK。
(2)保存模型:UtilityMenu >Files >Save as →输入Link_model.db→OK。
5.非线性求解设置
MainMenu>Solution>Analysis Type>Sol'n Controls→Automatic time stepping(自动时间步长):ON;Number ofsubsteps(载荷子步):10;Frequency(写出结果频率):Writelast substep only→OK。
6.按照载荷步依次求解
(1)第1载荷步
①施加载荷:MainMenu > Solution > Define loads > Apply > Structural >Force/Moment > On Nodes →拾取节点4→OK →Lab:FY;VALUE:-2133.9→OK。
②求解:MainMenu > Solution >Solve >Current LS →File >Close →Solve Current LoadStep →OK →Solution is done →Close。
(2)第2载荷步~第8载荷步
重复第(1)步,改变对应的载荷大小,求解。每个载荷步施加的载荷大小见下表。
(3)保存结果文件:UtilityMenu >Files >Save as →输入Link_Solve.db→OK。
7.后处理
(1)读入载荷步的结果:MainMenu >General Postproc >Read Results >By Pick →拾取想要看的载荷步→Read →Close。
(2)竖直位移云图:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →DOFsolution→Y-component of displacement (Y方向的位移)→OK。位移结果默认是在整体直角坐标系下。
(3)轴向应力云图:MainMenu>General Postproc>Plot Results >Contour Plot >Nodal Solu →Stress→X-component of stress (轴向应力)→OK。轴向应力结果是在单元坐标系下显示,轴向为单元坐标系的X方向。
(4)弹性应变云图:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu →Elastic Strain→X-component of elastic strain(弹性应变)→OK。也是在单元坐标系下显示。
(5)塑性应变云图:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu →Plastic Strain→X-component of plastic strain(塑性应变)→OK。也是在单元坐标系下显示。
(6)总应变云图:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu → Total Mechanical Strain→X-component of total mechanical strain(总应变)→OK。也是在单元坐标系下显示。
四、APDL步骤
/PREP7
ET,1,LINK180 !单元类型
R,1,10 !实常数
MP,EX,1,2e5
TB,BKIN !双线性随动强化(BKIN)可定义理想弹塑性
TBTEMP,0
TBDATA,1,250 !屈服应力
N,1,-100,0,0 !节点
N,2,0,0,0
N,3,100,0,0
N,4,0,-100,0
E,1,4 !单元
E,2,4
E,3,4
D,1,ALL !约束
D,2,ALL
D,3,ALL
FINISH
/SOLU
AUTOTS,ON !自动载荷步
NSUBST,10 !载荷子步
OUTRES,ALL,LAST !输出最后子步
F,4,FY,-2133.9 !加载
SOLVE !第1载荷步求解
F,4,FY,-4267.8 !加载:弹性极限载荷
SOLVE !第2载荷步求解
F,4,FY,-5151.7
SOLVE !第3载荷步求解
F,4,FY,-6035.5 !加载:塑性极限加载
SOLVE !第4载荷步求解
F,4,FY,-5151.7 !卸载
SOLVE !第5载荷步求解
F,4,FY,-4267.8 !卸载到施加的弹性极限载荷
SOLVE !第6载荷步求解
F,4,FY,-2133.9
SOLVE !第7载荷步求解
F,4,FY,0 !全卸载
SOLVE !第8载荷步求解
FINISH
/POST1
SET,,,,,,,2 !拾取想要看的载荷步
PLNSOL, S,X, 0,1.0 !应力云图
PLNSOL, EPEL,X, 0,1.0 !弹性应变云图
PLNSOL, EPPL,X, 0,1.0 !塑性应变云图
PLNSOL, EPTO,X, 0,1.0 !总应变云图
相关标签搜索：弹塑性专题-三杆对称桁架理想弹塑性ANSYS分析 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训
