ANSYS的log文件整理心得：解释GUI中产生FLST和FITEM

2017-03-02 by:CAE仿真在线来源:互联网

log文件整理心得
1.要注意时间,因为每次做的东西都会跟在log文件后面,所以要根据时间取舍,不是所有的log文件中的内容就有用的,一开始我建议从新建一个文件开始。
2.最好每做一步看一下log文件,可以知道自己的操作对应哪些命令
3.有些关于存盘、显示视角等命令可以删除。
4.选取实体时往往会产生很多命令,可以简化。
5.整理命令流时要新建立一个文本文件,以便从log文件中拷贝所需要的。
6.File菜单中的Read input from可以读入自己所建立的命令流来执行。
7.可以增加注释语句以增强可读性

下面以一简单模型为例大致说明一下:

/BATCH
/COM,ANSYS RELEASE 5.7.1 UP20010418 15:42:42 09/12/2003
/input,menust,tmp ,'',,,,,,,,,,,,,,,,1
/GRA,POWER
/GST,ON
/PLO,INFO,3
/COL,PBAK,ON,1,BLUE
这一段基本上没有用,是开始的设置,每个分析都是差不多这样,因此可以删除。

/PREP7
进入前处理器。在这一句前面可以加上fini /clear,这样可以把模型原来的内容清空。

!*
ET,1,PLANE42
!*
定义单元
   
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2e11
MPDATA,PRXY,1,,0.33
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,2700
定义材料类型

K,1,0,0,,
K,2,50,0,,
K,3,50,10,,
K,4,10,10,,
K,5,10,50,,
K,6,0,50,,
建立关键点

FLST,2,6,3
FITEM,2,1
FITEM,2,2
FITEM,2,3
FITEM,2,4
FITEM,2,5
FITEM,2,6
A,P51X
将几个关键点连接成面
这里,关键点是通过鼠标选取而得到,因此命令较多,其实这一段可以改为,A,1,2,3,4,5,6,具体如何改写可以参考FLST,FITEM命令的帮助

ESIZE,1,0,
设置单元大小

CM,_Y,AREA
ASEL, , , , 1
CM,_Y1,AREA
CHKMSH,'AREA'
CMSEL,S,_Y
!*
AMESH,_Y1
EPLOT
这一段的含义是对所选择的面1进行网格划分,可以改写成AMESH,1。

FINISH
退出前处理器
/SOLU
进入求解器

FLST,2,1,4,ORDE,1
FITEM,2,5
!*
/GO
DL,P51X, ,ALL,
给选择的线加位移约束。
可以改写成:DL,5,,ALL

FLST,2,2,4,ORDE,2
FITEM,2,2
FITEM,2,-3
/GO
!*
SFL,P51X,PRES,1000,
给选择的线加压力
可以改写成SFL,3,PRES,1000 SFL,2,PRES,1000

SOLVE
求解
FINISH
退出求解器

/POST1
进入后处理器
SET,FIRST
读出第一个解集
PLNSOL,U,SUM,0,1
画出节点位移解。

因此整理后的命令流文件如下:
fini
/clear
/PREP7

!定义单元
ET,1,PLANE42

!定义材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2e11
MPDATA,PRXY,1,,0.33
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,2700

!建立模型
K,1,0,0,,
K,2,50,0,,
K,3,50,10,,
K,4,10,10,,
K,5,10,50,,
K,6,0,50,,
A,1,2,3,4,5,6,

!划分网格
ESIZE,1,0,
AMESH,1

FINISH
/SOLU

!添加约束
DL,5,,ALL
SFL,3,PRES,1000
SFL,2,PRES,1000

SOLVE
FINISH

/POST1
SET,FIRST
PLNSOL,U,SUM,0,1

FLST 和 FITEM 是在 GUI 方式中,为某一命令选择操作实体时产生的,反映在 log 文件中是一条 FLST 命令,跟着一条或几条 FITEM 命令,再跟着一条带有一个 P51X 的操作命令;

或者是一条 FLST 命令和若干条 FITEM 命令,跟着一条 FLST 命令和若干条 FITEM 命令,再跟着一条带有两个 P51X 的操作命令。

根据 ANSYS 的帮助文件,对 FLST 和 FITEM 的用法说明如下:

1 FLST 命令

FLST, NFIELD, NARG, TYPE, Otype, LENG

其中各参数说明如下:

NFIELD - 所选择实体对应操作命令的第几个参数 (field),注意操作命令的第一个域是命令本身,因此 NFIELD=2,表示是命令的第1个参数; NFIELD=3,表示是命令的第2个参数.....等。

NARG - 后续列表中的项数 (即后续 FITEM 命令行数)

TYPE - 所选择的实体类型,定义为:
1 - 节点编号;
2 - 单元编号;
3 - Keypoint 编号;
4 - Line 编号;
5 - Area 编号;
6 - Volume 编号;
7 - Trace points;
8 - 总体直角坐标系中的坐标值;
9 - 屏幕坐标选择 (在屏幕 X, Y 坐标中,值 (-1 to 1))

Otype - 数据排列方式,有两种方式:
NOOR - 数据是无序的 (默认);
ORDER - 数据是个有序的表 (例如对于 E,P51X 和 A,P51X 命令,其中数据的顺序与用 pick 方式选择时的顺序一致)。

LENG - 数据表长度 (后续 FITEM 命令的个数。如果 Otype = NOOR,LENG 应等于 NARG)

2 FITEM 命令

FITEM, NFIELD, ITEM, ITEMY, ITEMZ

其中各参数说明如下:

NFIELD - 所选择实体对应操作命令的第几个参数 (field),注意操作命令的第一个域是命令本身,因此 NFIELD=2,表示是命令的第1个参数; NFIELD=3,表示是命令的第2个参数;等。

ITEM - 所选择实体的编号;负值表示它与上一个 FITEM 组成一个范围,例如相连两个 FITEM 的 ITEM 值分别为 4 和 -8,则表示 4,5,6,7,8 全被选中。

ITEMY, ITEMZ - 当所选实体为坐标值时,分别为 Y 和 Z 坐标,此时 ITEM 为 X 坐标。

注意:对于给定的实体类型,如果 ITEM 的值大于该类实体的最大值,可能导致不可预料的后果。