搜索一个压力容器分析设计实例
2017-03-03 by:CAE仿真在线 来源:互联网
FINISH
/CLEAR,START
/CONFIG,NPROC,1 !Your CPU Number
!****************Parameter Define*******************
*SET,corrupt,1.5
*SET,NDTA,9
*SET,DTA,NDTA-corrupt
!Flange size
*SET,FLANG_D,420
*SET,FLANG_N,273
*SET,FLANG_A,219
*SET,FLANG_B,FLANG_A-2*DTA
*SET,FLANG_H,133
*SET,FLANG_C,55.5
*SET,FLANG_H1,15
*SET,FLANG_DF,270
*SET,FLANG_F,1.6
*SET,FLANG_R,5
!Shell size
*SET,SHELL_L,539.6
*SET,SHELL_DO,219
*SET,SHELL_DI,SHELL_DO-2*DTA
!Intergrade
*SET,INTER_H,200.6
*SET,INTER_H1,30
*SET,INTER_H2,40
*SET,INTER_DO2,70
*SET,INTER_DI2,INTER_DO2-2*DTA
*SET,INTER_R,60
*SET,INTER_R1,60
!Pressure
*SET,pi,5.2
*SET,flang_area,pi*(SHELL_DI/2)**2/((FLANG_DF/2)**2-(FLANG_B/2)**2)
*SET,inter_area,pi*(SHELL_DI/2)**2/((INTER_DO2/2)**2-(INTER_DI2/2)**2)
!****************Model Create*******************
/prep7
et,1,185
mp,ex,1,1.95e5
mp,nuxy,1,0.3
/TITLE,Creating Modling
!Create Up Flange
!Create Key
k,1,FLANG_B/2,FLANG_H
k,2,FLANG_A/2,FLANG_H
k,3,FLANG_A/2,FLANG_H-FLANG_H1
k,4,FLANG_N/2,FLANG_C
k,5,FLANG_D/2,FLANG_C
k,6,FLANG_D/2,FLANG_F
k,7,FLANG_DF/2,FLANG_F
k,8,FLANG_DF/2,0
k,9,FLANG_B/2,0
!Create Line From Key
*do,ii,1,8
l,ii,ii+1
*enddo
l,1,9
lfillt,2,3,FLANG_R
lfillt,3,4,FLANG_R
!Create Area From Line
AL,ALL
CM,FLANG_LOW,AREA
!Create Shell
CSYS,4
wpoff,0,FLANG_H
RECTNG,SHELL_DI/2,SHELL_DO/2,0,SHELL_L,
ASEL,S,LOC,Y,0,SHELL_L
!Create Intergrade
wpoff,0,SHELL_L
*GET,KPMAX, KP,, NUM,MAX
k,KPMAX+1,SHELL_DI/2,,
k,KPMAX+2,SHELL_DI/2,INTER_H1
k,KPMAX+3,INTER_DI2/2,INTER_H-INTER_H2
k,KPMAX+4,INTER_DI2/2,INTER_H
k,KPMAX+5,INTER_DI2/2+DTA,INTER_H
k,KPMAX+6,INTER_DI2/2+DTA,INTER_H-INTER_H2
k,KPMAX+7,SHELL_DI/2+DTA,INTER_H1
k,KPMAX+8,SHELL_DI/2+DTA,,
*do,i,KPMAX+1,KPMAX+7
l,i,i+1
*enddo
l,KPMAX+1,KPMAX+8
LFILLT,17,16,INTER_R, ,
LFILLT,17,18,INTER_R1+DTA, ,
LFILLT,20,21,INTER_R1, ,
LFILLT,21,22,INTER_R+DTA, ,
ALLSEL,ALL
LSEL,S, , ,16
LSEL,A, , ,17
LSEL,A, , ,18
LSEL,A, , ,24
LSEL,A, , ,25
CM,INNER_LINE,LINE
CMSEL,A,INNER_LINE
ALLSEL,ALL
ALLSEL,BELOW,AREA
CM,TEMP,LINE
ALLSEL,ALL
LSEL,U, , ,TEMP
AL,ALL
CMDELE,TEMP
!Rote Area
ALLSEL,ALL
CM,ALL_AREA,AREA
wpstyl,defa
*GET,KPMAX, KP,, NUM,MAX
k,KPMAX+1,,,,
k,KPMAX+2,,FLANG_H+SHELL_L+INTER_H,,
VROTAT,ALL_AREA, , , , , ,KPMAX+1,KPMAX+2 ,180, ,
VGLUE,ALL
/TITLE,Meshing Modling
TYPE,1
MAT,1
VSEL,S,LOC,Y,0,FLANG_H+SHELL_L
ESIZE,10,0,
VSWEEP,ALL
VSEL,S,LOC,Y,FLANG_H+SHELL_L,FLANG_H+SHELL_L+INTER_H
ESIZE,1,0,
VSWEEP,ALL
ALLSEL,ALL
NUMMRG,ALL, , , ,LOW
NUMCMP,ALL, , , ,LOW
!****************Load And Solve**********
FINISH
/SOL
/TITLE,Define Load Pressure
/REPLOT
ASEL,S,LOC,Z,0
DA,ALL,SYMM
ALLSEL,ALL
ASEL,S,LOC,Y,0
SFA,ALL,1,PRES,-flang_area
ASEL,S,LOC,Y,FLANG_H+SHELL_L+INTER_H
SFA,ALL,1,PRES,-inter_area
ALLSEL,ALL
wpro,,-90,
wpstyle,,,,,,1,,,
ASEL,S,LOC,X,FLANG_D/2
DA,ALL,ALL,
ALLSEL,ALL
VSEL,S,LOC,Z,0,FLANG_H+SHELL_L
ASLV,R
ASEL,S,LOC,X,SHELL_DI/2
SFA,ALL,1,PRES,pi
ALLSEL,ALL
LSEL,S, , ,INNER_LINE
ASLL,R
wpstyl,defa
wpoff,,FLANG_H+SHELL_L+INTER_H1
ASEL,U,LOC,Z,0
LSLA,R
LSLA,S
LSEL,R,LOC,X,0
ASLL,S
ASEL,U,LOC,X,0
SFA,ALL,1,PRES,pi
ALLSEL,ALL
SOLVE
FINISH
/POST1
/TITLE,Giving The Stress Intensity Plot
PLNSOL,S,INT,0,1
相关标签搜索：一个压力容器分析设计实例 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训
