子模型应用实例（shell-to-solid）

2017-03-02 by:CAE仿真在线来源:互联网

!第一步总体模型建模及其分析求解
FINISH
/CLEAR,START
/FILNAM,FULL-MODEL
/TITLE,FULL,MODEL,SOLUTION

/PREP7
ET,1,SHELL63
R,1,0.02

MP,EX,1,2E11
MP,PRXY,1,0.3

RECTNG,0,1,0,0.1,
CYL4,0.5,0.05,0.02
ASBA,1,2

AATT,1,1,1,0,
ESIZE,0.03,0,
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
FINISH

/SOLU
ANTYPE,0
LSEL,S,LOC,X,0
DL,ALL,,ALL,

LSEL,S,LOC,Y,0.1
SFL,ALL,PRES,40,

LSEL,S,LOC,X,1
SFL,ALL,PRES,-1.6E5,

ALLS
SAVE
SOLVE
FINISH

/POST1
SET,LAST
/EFACET,1

plnsol,s,eqv,0,1.0

!第二步,子模型建模,定义切割边界节点文件
finisN
/FILNAM,SUBMODELING
/TITLE,SUBMODELING,SOLUTION

/PREP7
ACLEAR,ALL
CM,A1,AREA

ASEL,NONE
RECTNG,0,0.4,0,0.1
RECTNG,0.6,1,0,0.1
CM,A2,AREA
ALLS
ASBA,A1,A2
CM,A1,AREA

VEXT,A1,,,0,0,0.01
VEXT,A1,,,0,0,-0.01

ETDEL,1
ET,1,SOLID185
AATT,1,1,1,0
ESIZE,0.004,0,
VSWEEP,ALL

!第三步选择出切割边界节点,写进节点文件CUT-BC.node
NSEL,S,LOC,X,0.4
NSEL,A,LOC,X,0.6
NPLOT
!写出子模型切割边界上的节点文件
NWRITE,'CUT-BC','NODE',' ',0

ALLS
SAVE
FINISH

!第四步调入总体模型,将总体模型的位移结果插值到子模型的切割边界节点上
/FILNAM,FULL-MODEL
RESUME
/POST1
FILE,'FULL-MODEL','RST','.'
SET,LAST

!写出子模型切割边界上的位移约束定义条件
CBDOF,'CUT-BC','NODE','','U-CUT-BC','CBDO','',0,START,1
FINISH

!第五步调入子模型,首先进入前处理器读入切割边界旋转角定义,
!然后,进入求解器读入切割边界节点位移定义,并将其他载荷施加
!到子模型上,最后进行子模型求解
/FILNAM,SUBMODELING
RESUME
/PREP7
!修正子模型切割边界节点的旋转角
/INPUT,'U-CUT-BC','CBDO','',,0
EPLOT
FINISH

/SOL
ANTYPE,0
!施加切割边界位移约束
/INPUT,'U-CUT-BC','CBDO','',:START,0

ASEL,S,LOC,Y,0.1
SFA,ALL,1,PRES,2E3!施加上表面压力

ALLS
SAVE
SOLVE
FINISH

/POST1
SET,LAST
/EFACET,1
PLNSOL,S,EQV,0,1.0

开放分享：优质有限元技术文章,助你自学成才