ANSYS时程分析重启动例子 【转】

这是自己最近做的一个例子,一是为了感谢okok论坛给与我的很大的帮助,二是起到抛砖引玉的作用.因为我觉得这个技术是很有用的,特别是对于计算时间特别长的模型,可以分成几段计算,这可以避免由于意外中断等原因重复以前的计算工作.下面时我的命令流(经过验证与没有使用重启动分析结果完全一致):
finish
/clear,nostart !
/config,nres,2000
/CWD,'E:\graduate design\FEM\beam\transient\seismic\restart'
/filnam,restart,1
/title,restart
/PREP7
ET,1,BEAM3
R,1,1,0.83333e-1,1, , , ,
MP,EX,1,200e9
MP,DENS,1,7.8e3
N,1
N,201,200
FILL
E,1,2
EGEN,200,1,1
D,1,UX,,,,,Uy
D,201,Uy
finish

/SOLU! Enter SOLUTION
ANTYPE,TRANS! Transient analysis
TRNOPT,FULL! Full method
rescontrol,define,50,last!将第50载荷步的最后一个子载荷步写入.Rnnn文件
rescontrol,define,100,last!将第100载荷步的最后一个子载荷步写入.Rnnn文件
!另外默认的还会将最后一个载荷步的最后一个子载荷步写入.Rnnn文件
!
!从文件中读取地震波付给数组
*dim,tjwe,,1000,1
*dim,tjns,,1000,1
*dim,tjud,,1000,1

*CREATE,ansuitmp
*VREAD,tjwe,'tjwe1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
!*
*CREATE,ansuitmp
*VREAD,tjns,'tjns1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
!*
*CREATE,ansuitmp
*VREAD,tjud,'tjud1D','txt',' ',1, , , , , ,
(F7.4)
*END
/INPUT,ansuitmp
deltt=0.01!测量时间间隔.01s
betad,0.1462
KBC,0
outres,basic,all
parsave,all,parameter!保存参数,这对下面的重分析是必须的,因为这些参数是没有存入.RDB文件的
*status!列出APDL信息
*do,i,1,500,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish
!重启动分析
/solu
antype,,restart,500,1
parres,,parameter!重新载入参数
*status
rescontrol,define,700,last!将第700载荷步的最后一个子载荷步写入.Rnnn文件
rescontrol,define,800,last!将第800载荷步的最后一个子载荷步写入.Rnnn文件

*do,i,501,1000,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish

/post26
NSOL,2,101,U,Y,UY_2
XVAR,1
PLVAR,2
/gropts,view,1!可以使图形能够用鼠标进行缩放